Random game
Random demo
Random game
  • Entry name:
     Player-Missile Demo (Flop 1 magazine intro) 
  • Category:
    Demos/Intros
  • Publisher/Developer:
    Flop 1
  • Atari conversion:
    Roy Goring
  • Media format:
    Diskette
  • Programming language:
    Turbo Basic XL
  • Entry name:
    Player-Missile Demo (Flop 1 magazine intro)
  • Category:
    Demos/Intros
  • Publisher/Developer:
    Flop 1
Player-Missile Demo (Flop 1 magazine intro) Player-Missile Demo (Flop 1 magazine intro) Player-Missile Demo (Flop 1 magazine intro) Player-Missile Demo (Flop 1 magazine intro) Player-Missile Demo (Flop 1 magazine intro) Player-Missile Demo (Flop 1 magazine intro) Player-Missile Demo (Flop 1 magazine intro)
Listing 1
1 REM *******************************
2 REM * PLAYER-MISSILE DEMO *
3 REM * *
4 REM * BY ROY GORING *
5 REM * *
6 REM * z casopisu Page 6 *
7 REM * *
8 REM * [ AK Trebic ] *
9 REM *******************************
10 ------------------------------
30 ------------------------------
50 GO# MAIN_PROG
99 ------------------------------
100 PROC INITIALISE
110 GRAPHICS 3+16
120 PMADR=PEEK(106)-16:​PMBASE=PMADR*256:​POKE 54279,​PMADR:​POKE 106,​PMADR
130 POKE 559,​62:​POKE 53277,​3
140 FOR I=0 TO 2048:​POKE PMBASE+I,​0:​NEXT I
150 FOR A=0 TO 3:​POKE 53248+A,​0:​NEXT A
160 CHBASE=57344:​POKE 704,​202:​POKE 705,​90:​POKE 706,​138:​POKE 707,​26
170 ENDPROC
199 ------------------------------
200 PROC PLAYER0
202 EXEC MUS
205 C=0
210 FOR A=0 TO 15
215 READ D:​D=D-32
220 MOVE CHBASE+(D*8),​PMBASE+1050+C,​8
225 C=C+8
230 NEXT A
235 POKE 53248,​60
240 FOR E=1 TO 230
245 -MOVE PMBASE+1024,​PMBASE+1024+1,​256
250 PAUSE 1
255 MOVE PMBASE+1270,​PMBASE+1040,​1
260 NEXT E
262 EXEC MUS
265 ENDPROC
299 ------------------------------
300 PROC PLAYER1
302 PAUSE 20:​EXEC MUS
305 C=0
310 FOR A=0 TO 13
315 READ D:​D=D-32
320 MOVE CHBASE+(D*8),​PMBASE+1306+C,​8
325 C=C+8
330 NEXT A
335 X=0
340 REPEAT
345 POKE 53249,​X:​X=X+1
350 PAUSE 1
355 UNTIL X=255
360 X=0
365 REPEAT
370 POKE 53249,​X:​X=X+1
375 PAUSE 1
380 UNTIL X=100
382 EXEC MUS
385 ENDPROC
399 ------------------------------
400 PROC PLAYER2
402 PAUSE 20:​EXEC MUS
405 C=0
410 FOR A=0 TO 14
415 READ D:​D=D-32
420 MOVE CHBASE+(D*8),​PMBASE+1562+C,​8
425 C=C+8
430 NEXT A
435 X1=255
440 WHILE X1<>0
445 POKE 53250,​X1:​X1=X1-1
450 PAUSE 1
455 WEND
460 X1=255
465 WHILE X1<>140
470 POKE 53250,​X1:​X1=X1-1
475 PAUSE 1
480 WEND
482 EXEC MUS
485 ENDPROC
499 ------------------------------
500 PROC PLAYER3
505 SOUND 0,​10,​12,​15:​PAUSE 5:​SOUND
510 POKE 53251,​180:​C=0
515 # LABEL1
520 GET D:​D=D-32
525 IF D=155-32 OR C>207
530 GO# LABEL2
535 ELSE
540 MOVE CHBASE+(D*8),​PMBASE+1820+C,​8
545 C=C+8
550 GO# LABEL1
555 ENDIF
560 # LABEL2
565 FOR E=1 TO 230
570 MOVE PMBASE+1792,​PMBASE+1792-1,​256
575 PAUSE 1
580 MOVE PMBASE+1816,​PMBASE+2047,​1
585 NEXT E
590 ENDPROC
599 ------------------------------
600 PROC MOVE
605 FOR I=0 TO 1020
610 -MOVE PMBASE+1024,​PMBASE+1024+1,​256
615 MOVE PMBASE+1270,​PMBASE+1040,​1
620 POKE 53249,​X:​X=X+1
625 IF X=255 THEN X=0
630 POKE 53250,​X1:​X1=X1-1
635 IF X1=0 THEN X1=255
640 MOVE PMBASE+1792,​PMBASE+1792-1,​256
645 MOVE PMBASE+1816,​PMBASE+2047,​1
650 NEXT I
655 ENDPROC
699 ------------------------------
700 PROC PLAYERN
705 POKE 53251,​180:​C=0
710 FOR A=0 TO 15
715 READ D:​D=D-32
720 MOVE CHBASE+(D*8),​PMBASE+1820+C,​8
725 C=C+8
726 PAUSE 20:​EXEC MUS
730 NEXT A
735 FOR E=1 TO 230
740 MOVE PMBASE+1792,​PMBASE+1792-1,​256
745 PAUSE 1
750 MOVE PMBASE+1816,​PMBASE+2047,​1
755 NEXT E
756 FOR I=0 TO 4:​EXEC MUS:​PAUSE 15:​NEXT I
760 ENDPROC
799 ------------------------------
800 PROC MUS
810 SOUND 0,​T*9+1,​12,​15:​PAUSE 5:​SOUND
820 T=T+1:​IF T>1 THEN T=0
830 ENDPROC
1999 ------------------------------
2000 # MAIN_PROG
2010 EXEC INITIALISE
2020 EXEC PLAYER0
2030 EXEC PLAYER1
2040 EXEC PLAYER2
2050 EXEC PLAYERN
2055 PAUSE 100
2060 EXEC MOVE
2065 PAUSE 100
2066 FOR I=53248 TO 53251:​POKE I,​0:​PAUSE 20:​NEXT I
2070 RUN "D:​START.TBS"
2999 ------------------------------
3000 DATA 32,​42,​32,​65,​84,​65,​82,​73,​32,​75,​76,​85,​66,​32,​42,​32
3010 DATA 32,​32,​32,​42,​32,​84,​82,​69,​66,​73,​67,​32,​42,​32
3020 DATA 32,​32,​32,​42,​32,​90,​68,​82,​65,​86,​73,​32,​42,​32,​32
3030 DATA 42,​32,​65,​84,​65,​82,​73,​83,​84,​89,​32,​42,​32,​42,​32,​42	

This is non-commercial site, its content is based on Atari 8-bit home computer contents and references.
If you feel your rights are violated by showing/using any part of contents of your product represented on this page, please contact me immediatelly so I can remove it!