Atari 8-bit Source code

1 GRAPHICS 0:​POKE 752,​1:​SETCOLOR 2,​7,​0:​SETCOLOR 4,​9,​4:​SETCOLOR 1,​7,​10
12 POKE 82,​1:​OPEN #2,​4,​0,​"K:​"
15 DIM N$(50),​Z$(40),​L$(50),​M(6),​IO(6),​L(6),​T$(3),​T1$(3),​A1$(40),​A2$(40),​A$(30),​D$(102),​R$(4),​O$(39),​S$(6),​B$(1)
16 DIM D(6),​H$(16),​M$(140),​P(6)
17 FOR I=1 TO 6:​L(I)=0:​NEXT I
18 FOR T=1 TO 50:​N$(T,​T)=" ":​NEXT T:​L$=N$:​O$=N$(1,​39)
20 A1$=" ":​A1$(3,​3)=CHR$(25):​A1$(LEN(A1$)+1)=A1$:​A2$="______________________________________ "
22 A1$(LEN(A1$)+1)=" ":​GOSUB 420
25 ? " "
30 ?:​?:​? " How many players (up to 4) ? ";
40 GET #2,​N:​N=N-48:​IF N<1 OR N>4 THEN 40
42 ? N
45 ?:​?
50 FOR I=1 TO N:​? " Who is player #";I;:​INPUT Z$:​N$(I*10-9,​I*10)=Z$:​M(I)=100:​IO(I)=0
52 L(I)=0:​NEXT I:​N$(I*10-9,​I*10)="ATARI ":​M(I)=100:​IO(I)=0:​N=N+1:​?:​? " Do you need to see instructions?";
60 GET #2,​B:​IF CHR$(B)="Y" THEN GOSUB 1370
70 FOR IP=1 TO N
80 ? "":​POSITION 0,​0:​? "  ":​? " ";
81 SETCOLOR 2,​2,​0:​SETCOLOR 4,​2,​4:​SETCOLOR 1,​2,​10
82 FOR J=1 TO N:​? N$(J*10-9,​J*10);" ";:​? " $";M(J):​POSITION 35,​J+1:​? IO(J):​NEXT J:​?:​GOSUB 200
84 ? " It is your turn ";N$(IP*10-9,​IP*10):​?:​IF M(IP)>=0 THEN 100
90 IO(IP)=IO(IP)+1:​M(IP)=M(IP)+100:​IF M(IP)<=0 THEN 90
92 ? " You must borrow money to continue to play and pay it back to the bank .... plus interest!"
94 FOR TI=1 TO 800:​NEXT TI:​GOSUB 1470
95 GOTO 80
100 IF IO(IP)<=0 OR M(IP)<110 THEN 130
110 PB=INT(M(IP)/110):​IF PB>IO(IP) THEN PB=IO(IP)
120 IO(IP)=IO(IP)-PB:​M(IP)=M(IP)-110*PB:​? " You can pay back ";PB;" IOU note(s)":​? " at 110 dollars each.":​?
122 FOR TI=1 TO 800:​NEXT TI
130 IF L(IP)=3 THEN 160
132 ? " Would you like to buy a lottery ticket for $10 ? ";
140 IF IP=N THEN ? "Y":​GOTO 154
150 GET #2,​B:​IF CHR$(B)="N" THEN 160
152 IF CHR$(B)<>"Y" THEN 150
154 ? CHR$(253):​GOSUB 260:​L(IP)=L(IP)+1:​L$(IP*9+L(IP)*3-11,​IP*9+L(IP)*3-8)=T$:​M(IP)=M(IP)-10
156 FOR TI=1 TO 400:​NEXT TI:​GOTO 80
160 ?:​POSITION 6,​20:​? "Hit any key to continue ";
170 GET #2,​B:​GOSUB 290
180 ON GN GOSUB 1020,​810,​460,​1130,​1170,​1190,​460,​1200,​1230,​1240,​460,​750,​1300,​940,​1020,​710,​810,​1310,​1320,​750,​460
182 IF GN>21 THEN ON GN-21 GOSUB 1330,​710,​810,​1340,​1350,​1330,​810,​460,​940,​1310,​710,​750,​1360,​810,​710,​710
190 IP=IP+1:​IF IP>N THEN 70
192 GOTO 80
200 HM=M(1):​HN=1:​FOR J=2 TO N:​IF M(J)>HM THEN HM=M(J):​HN=J:​NEXT J:​GOTO 210
202 NEXT J
210 IF HM<1000 THEN RETURN
220 K=0:​FOR J=1 TO N:​IF M(J)=HM THEN K=K+1
222 NEXT J
230 IF K>1 THEN ? " Since there's a tie,​ keep going":​?:​RETURN
240 ?:​? N$(HN*10-9,​HN*10);" wins this game with ":​? HM;" dollars!"
242 FOR T=1 TO 100:​SOUND 0,​T,​10,​10:​FOR TI=1 TO 5:​NEXT TI:​SOUND 0,​255-T,​10,​10:​FOR TI=1 TO 5:​NEXT TI:​NEXT T
244 SOUND 0,​0,​0,​0:​SOUND 1,​0,​0,​0
248 ?:​? " Would you like to play again ?";
250 GET #2,​B:​IF CHR$(B)="Y" THEN RUN:​IF CHR$(B)="N" THEN END
251 IF CHR$(B)<>"Y" THEN 250
260 T$=" - ":​T$(1,​1)=CHR$(49+INT(RND(0)*5)):​T1$=CHR$(49+INT(RND(0)*6)):​IF T1$<=T$ THEN 260
262 T$(3,​3)=T1$:​FOR I=1 TO N:​IF L(I)=0 THEN 280
270 FOR J=1 TO L(I):​IF T$=L$(I*9+J*3-11,​I*9+J*3-9) THEN 260
272 NEXT J
280 NEXT I:​?:​? " You receive ticket number ";T$:​RETURN
290 POKE 752,​1:​RESTORE:​? "":​POSITION 1,​0:​? A2$;:​FOR J=1 TO 18:​? A1$;:​NEXT J:​? A2$;
300 FOR X=1 TO 18:​READ A$:​POSITION 4,​X:​? A$:​READ A$:​POSITION 23,​X:​? A$:​NEXT X
310 X=1:​X1=2:​POKE 752,​1:​POKE 764,​255:​POSITION 2,​22:​? "Touch any key,​ ";N$(IP*10-9,​IP*10);
320 Y=X:​Y1=X1:​POSITION X1,​X:​? CHR$(160);:​X=INT(RND(0)*18)+1:​X1=INT(RND(0)*2)*19+2
322 FOR S=X*2+X1/21+50 TO X*2+X1/21+42 STEP -4:​SOUND 0,​S,​10,​10:​NEXT S:​SOUND 0,​0,​0,​0
330 IF IP=N AND RND(0)<0.03334 THEN 360
340 IF IP<>N THEN B=PEEK(764):​IF B<>255 THEN 360
350 POSITION Y1,​Y:​? " ";:​GOTO 320
360 POKE 764,​255:​JJ=25:​FOR I=1 TO 6+INT(RND(0)*4):​FOR J=1 TO JJ:​NEXT J:​JJ=JJ+25:​POSITION Y1,​Y:​? " ";:​Y=X:​Y1=X1
361 SOUND 0,​X*2+X1/21+30,​10,​10:​SOUND 0,​X*2+X1/21+40,​10,​10:​SOUND 0,​0,​0,​0
362 POSITION X1,​X:​? CHR$(160);:​IF X1=2 THEN X1=21:​GOTO 370
364 X1=2:​X=X+1:​IF X=19 THEN X=1
370 NEXT I
380 FOR TI=1 TO 150:​NEXT TI:​GN=X*2+INT(X1/13)-2:​POSITION Y1,​Y:​? " ";:​FOR I=1 TO 5:​POSITION Y1,​Y:​? CHR$(160);
381 FOR S=10 TO 120 STEP 10:​SOUND 0,​S,​10,​10:​NEXT S:​FOR S=110 TO 0 STEP -10:​SOUND 0,​S,​10,​10:​NEXT S
382 FOR TI=1 TO 30:​NEXT TI:​POSITION Y1,​Y:​? " ";:​FOR TI=1 TO 30:​NEXT TI:​NEXT I:​POKE 752,​0:​RETURN
390 DATA POKERPARTY,​,​SWEEP$TAKES!,​LOVE A NEIGHBOR,​EZ COME EZ GO,​WIN A FEW
392 DATA SWEEP$TAKES!,​UNLUCKY SEVEN,​LOSE A FEW
400 DATA EVEN STEVEN,​SWEEP$TAKES!,​DAILY DOUBLE,​POT LUCK,​HIGH ROLLER,​POKERPARTY,​LOTTERY,​
402 DATA ******,​$100.00 BONU$,​OFF TO THE RACES,​SWEEP$TAKES!,​LOSE THIS TURN
410 DATA LOTTERY,​,​TAX TIME,​`BONANZA`,​LOSE THIS TURN,​,​SWEEP$TAKES!,​HIGH ROLLER
412 DATA ******,​LOTTERY,​HORSE RACE,​MAD MONEY,​,​MAY BE NEXT TIME
420 D$=""
450 RETURN
460 POKE 752,​1:​? "";:​? " ":​?:​? " GH"
462 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
464 ? " A C E":​? " | | |"
470 ?:​?:​?:​? " | | |":​? "P=Pair B D F"
472 ? "S=StraightIJ"
480 FOR X=1 TO 6:​POSITION X*6-2,​5:​? D$(X*17-16,​X*17);:​NEXT X
490 POSITION 1,​12:​? "Do you need Sweepstakes instructions ?";:​POKE 764,​255
500 GET #2,​B
510 IF CHR$(B)="N" THEN 540
512 POSITION 1,​12:​? "In Sweepstakes everyone antes $10. Theneach player bets on the outcome of the";
514 ? " roll of 6 dice.There are three types ofbets.":​GOSUB 1470
520 POSITION 1,​12:​? "One way is to bet on where the highest number rolled will appear. If the high";
522 ? "number appears in A,​B,​C,​D,​E or F you win $300. Letters G,​H,​I and J cover ";
524 ? "two spots. If you bet G,​ you cover spots A and C and can win $150."
530 GOSUB 1470:​POSITION 1,​12:​? "Another bet is <<P>> for pairs. if twodice next to one another match,​ you win";
532 ? "$200. The third bet is <<S>> for a straight. If 3 consecutive dice appear";
535 ? "in numerical order,​ you win $450. ";O$:​GOSUB 1470
540 FOR I=12 TO 18:​POSITION 1,​I:​? O$;:​NEXT I:​POSITION 30,​12:​? "A-F $300":​POSITION 30,​13:​? "G-J $150"
542 POSITION 32,​14:​? "P $200":​POSITION 32,​15:​? "S $450":​FOR I=1 TO N:​M(I)=M(I)-10:​S$(I,​I)=" ":​NEXT I
544 POSITION 10,​23:​? "Place your bets:​";:​X=12
550 FOR J=IP TO N:​POSITION 1,​X:​? N$(J*10-9,​J*10);" - ";:​X=X+1
560 IF J=N THEN B$=CHR$(65+RND(0)*11):​IF B$="K" THEN B$="P"
562 IF J=N THEN 580
570 GET #2,​B:​B$=CHR$(B):​IF (B$>"@" AND B$<"K") OR B$="P" OR B$="S" THEN 580
572 GOTO 570
580 FOR K=1 TO N:​IF B$=S$(K,​K) THEN 560
582 NEXT K:​? B$;:​S$(J,​J)=B$:​NEXT J
590 IF IP=1 THEN HN=1:​GOTO 620
592 FOR J=1 TO IP-1:​POSITION 1,​X:​? N$(J*10-9,​J*10);" - ";:​X=X+1
600 GET #2,​B:​B$=CHR$(B):​IF (B$>"@" AND B$<"K") OR B$="P" OR B$="S" THEN 610
602 GOTO 600
610 FOR K=1 TO N:​IF B$=S$(K,​K) THEN 600
612 NEXT K:​? B$;:​S$(J,​J)=B$:​NEXT J:​HN=1
620 GOSUB 1470:​POSITION 1,​5:​? O$(1,​37):​? O$(1,​37):​? O$(1,​37):​FOR X=1 TO 6:​FOR L=1 TO 5:​D(X)=INT(RND(0)*6+1)
622 POSITION X*6-2,​5:​? D$(D(X)*17-16,​D(X)*17);:​NEXT L:​IF D(X)>HN THEN HN=D(X)
624 NEXT X
628 FOR I=12 TO 15:​POSITION 30,​I:​? " ";:​NEXT I
630 FOR J=1 TO N:​X=12+(J-IP):​IF X<12 THEN X=X+N
631 POSITION 30,​X:​? " ";:​POSITION 14,​X:​IF S$(J,​J)<>"P" THEN 640
632 FOR K=1 TO 5:​IF D(K)=D(K+1) THEN ? "$200 for a pair":​M(J)=M(J)+200:​K=5:​GOTO 690
634 NEXT K:​? "Sorry,​ no pairs!":​GOTO 690
640 IF S$(J,​J)<>"S" THEN 660
642 FOR K=1 TO 4:​IF D(K)=D(K+1)-1 AND D(K)=D(K+2)-2 THEN ? "$450 for the straight":​M(J)=M(J)+450:​GOTO 690
644 NEXT K
650 ? "No straight!":​GOTO 690
660 IF (S$(J,​J)="G" AND (D(1)=HN OR D(3)=HN)) OR (S$(J,​J)="H" AND (D(3)=HN OR D(5)=HN)) THEN 668
662 IF (S$(J,​J)="I" AND (D(2)=HN OR D(4)=HN)) OR (S$(J,​J)="J" AND (D(4)=HN OR D(6)=HN)) THEN 668
664 GOTO 670
668 ? "$150 for bet on ";S$(J,​J):​M(J)=M(J)+150:​GOTO 690
670 IF S$(J,​J)<="@" OR S$(J,​J)>="G" THEN 680
672 K=ASC(S$(J,​J))-64:​IF D(K)=HN THEN ? "$300 on spot ";S$(J,​J):​M(J)=M(J)+300:​GOTO 690
674 ? "You lose with spot ";S$(J,​J);:​GOTO 690
680 ? "Maybe next time!"
690 NEXT J
700 GOSUB 1470:​RETURN
710 POKE 752,​1:​? "";:​? " ":​?:​? " If both the numbers on your ticket are";
711 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
712 ? " among the six numbers rolled,​ you will receive $50 for that ticket.":​? " Here we go..."
714 FOR J=1 TO N:​POSITION 1,​10+J:​? N$(J*10-9,​J*10);" ";L$(J*9-8,​J*9-6);" ";L$(J*9-5,​J*9-3);" ";L$(J*9-2,​J*9)
716 NEXT J:​GOSUB 1470
720 FOR J=1 TO 6:​D(J)=0:​NEXT J:​FOR J=1 TO 6:​K=INT(RND(0)*6)+1:​POSITION J*6-2,​7:​? D$(K*17-16,​K*17):​D(K)=1
722 NEXT J
730 FOR J=1 TO N:​IF L(J)=0 THEN 738
731 FOR K=1 TO L(J):​FOR L=1 TO 150:​NEXT L
732 IF D(VAL(L$(J*9+K*3-11,​J*9+K*3-11)))=1 AND D(VAL(L$(J*9+K*3-9,​J*9+K*3-9)))=1 THEN 735
734 POSITION 10+K*6,​10+J:​? "---";:​SOUND 0,​220,​10,​10:​FOR TI=1 TO 100:​NEXT TI:​GOTO 737
735 POSITION 10+K*6,​10+J:​? "$50";:​M(J)=M(J)+50:​FOR S=30 TO 10 STEP -2:​SOUND 0,​S,​10,​10:​FOR TI=1 TO 2:​NEXT TI
736 SOUND 0,​255-S,​10,​10:​FOR TI=1 TO 2:​NEXT TI:​NEXT S
737 SOUND 0,​0,​0,​0:​NEXT K:​L(J)=0
738 NEXT J:​FOR J=1 TO N*9:​L$(J,​J)=" ":​NEXT J
740 GOSUB 1470:​FOR J=1 TO N*9:​L$(J,​J)=" ":​NEXT J:​L(2)=0:​L(3)=0:​RETURN
750 ? "";:​POKE 752,​1:​H$="   ":​FOR J=1 TO 6:​D(J)=10:​POSITION 2,​J*3+1:​? J;" ";H$;:​NEXT J
751 SETCOLOR 2,​12,​0:​SETCOLOR 4,​12,​4:​SETCOLOR 1,​12,​10
752 FOR J=1 TO N:​POSITION 1,​J*3+1:​? N$(J*10-9,​J*10);:​M(J)=M(J)-20:​NEXT J:​POSITION 9,​0:​? ""
754 FOR Y=1 TO 6:​POSITION 38,​Y*3+1:​? ".";:​NEXT Y
760 POSITION 1,​21:​? "Everyone has bet $20,​ the winner will receive $100.":​GOSUB 1470
770 SOUND 0,​250,​8,​10:​SOUND 0,​240,​8,​10:​SOUND 0,​255,​8,​10:​SOUND 0,​0,​0,​0
780 K=INT(RND(0)*6)+1:​D(K)=D(K)+1:​POSITION D(K),​K*3+1:​? H$;:​IF D(K)<33 THEN 770
790 POSITION 1,​21:​? O$(1,​38);:​? O$(1,​38);:​? O$(1,​38);:​POSITION 1,​21:​IF K>N THEN 794
792 ? N$(K*10-9,​K*10);" ";:​M(K)=M(K)+100:​GOTO 800
794 SOUND 0,​0,​0,​0:​? "Horse number ";K;" ";
800 ? "wins this race!":​GOSUB 1470:​POKE 752,​0:​RETURN
810 M$="":​? "":​POSITION 7,​4:​? ":​":​K=1:​M=10*INT(RND(0)*5+1)+50
820 IF RND(0)<0.2 THEN M$="Hold a Sweepstakes.":​K=2:​GOTO 890
830 IF RND(0)<0.2 THEN M$="Hold a Lottery.":​K=3:​GOTO 890
840 IF RND(0)<0.5 THEN M$="Collect from ":​K=-1:​GOTO 850
842 M$="Pay to "
850 J=INT(RND(0)*(N+1)+1):​IF J<>IP THEN 860
852 M$(LEN(M$)+1)="everyone":​M(IP)=M(IP)-K*N*M:​FOR J=1 TO N:​M(J)=M(J)+K*M:​NEXT J:​GOTO 880
860 IF J=N+1 THEN M$(LEN(M$)+1)="the bank":​M(IP)=M(IP)-K*M:​GOTO 880
870 M$(LEN(M$)+1)=N$(J*10-9,​J*10):​M(IP)=M(IP)-K*M:​M(J)=M(J)+K*M
880 M$(LEN(M$)+1)=" ":​M$(LEN(M$)+1)=STR$(M):​M$(LEN(M$)+1)=" dollars."
890 QQ=0
900 FOR TI=LEN(M$) TO 1 STEP -1:​M$(TI+44,​TI+44)=M$(TI,​TI):​NEXT TI:​M$(1,​32)=O$(1,​32):​M$(33,​42)=N$(IP*10-9,​IP*10)
901 M$(43,​44)=",​ ":​M$(LEN(M$)+1)=O$(1,​32)
902 FOR J=1 TO LEN(M$)-30:​SOUND 0,​200,​8,​10:​POSITION 5,​6:​? M$(J,​J+30);:​SOUND 0,​0,​0,​0:​FOR TI=1 TO 5:​NEXT TI
903 NEXT J:​M$=""
910 GOSUB 1470
930 IF K=2 THEN 460
932 IF K=3 THEN 710
934 RETURN
940 POKE 752,​1:​? "";:​? "-- Everyone antes $20 and rolls two dice. The"
941 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
942 ? " highest roll takes the $100 prize. To roll dice,​touch any key on your turn.":​GOSUB 1470
950 FOR J=1 TO N:​M(J)=M(J)-20:​POSITION 1,​2+J*3:​? N$(J*10-9,​J*10):​X1=12+(J-INT(J/2)*2)*4:​X=2+J*3:​GOSUB 1450:​D(J)=K
952 X1=X1+8:​GOSUB 1450:​D(J)=D(J)+K:​POSITION 28,​X:​? "Total is ";D(J);:​NEXT J
960 HN=D(1):​HM=1:​FOR J=2 TO N:​IF D(J)>HN THEN HN=D(J):​HM=J
962 NEXT J
970 K=0:​FOR J=1 TO N:​IF D(J)=HN THEN K=K+1
972 NEXT J
980 IF K=1 THEN POSITION 1,​20:​? N$(HM*10-9,​HM*10);" wins the pot!":​M(HM)=M(HM)+100:​POKE 764,​255:​GOSUB 1470:​RETURN
990 POSITION 1,​20:​? "We've got a tie! Those high rollers will roll again!":​POKE 764,​255:​GOSUB 1470
991 ? "";
992 POSITION 1,​5:​FOR J=1 TO 18:​? D$;:​NEXT J
1000 FOR J=1 TO N:​X1=14:​X=2+3*J:​IF D(J)<HN THEN D(J)=0:​NEXT J:​GOTO 960
1002 POSITION 1,​X:​? N$(J*10-9,​J*10):​X1=12+(J-INT(J/2)*2)*4:​GOSUB 1450:​D(J)=K:​X1=X1+8:​GOSUB 1450
1004 D(J)=D(J)+K:​POSITION 28,​X:​? "Total is ";D(J);:​X=X+3:​NEXT J
1010 GOTO 960
1020 POKE 752,​1:​? "";:​? "-- Each player pays $20 and rolls three dice. "
1021 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
1022 ? "The best poker hand...":​? "(Three of a kind > Straight > Pair) wins $100.Touch any key to roll dice.";
1024 GOSUB 1470:​XX=6:​FOR I=1 TO N:​M(I)=M(I)-20:​NEXT I:​HM=0
1030 FOR I=1 TO N:​POSITION 1,​XX:​? N$(I*10-9,​I*10):​FOR M=1 TO 3:​J=I:​X1=9+M*6:​X=XX:​POKE 764,​255:​GOSUB 1450:​D(M)=K
1032 NEXT M:​P(I)=0
1040 FOR TI=1 TO 100:​NEXT TI:​FOR TI=X TO XX+2:​POSITION 11,​TI:​? O$(1,​28);:​NEXT TI:​POSITION 13,​XX
1041 ? D(1);" ";D(2);" ";D(3);" ";
1042 IF D(1)=D(2) AND D(1)=D(3) THEN ? "Three of a kind!";:​P(I)=30+D(1):​GOTO 1100
1050 IF D(1)=D(2) THEN P(I)=10+D(1)
1052 IF D(1)=D(3) THEN P(I)=10+D(1)
1054 IF D(2)=D(3) THEN P(I)=10+D(2)
1060 IF P(I)>0 THEN ? "A pair!";:​GOTO 1100
1070 FOR J=1 TO 3:​IF (D(1)=D(2)+1 AND D(1)=D(3)+2) OR (D(1)=D(2)-1 AND D(1)=D(3)-2) THEN P(I)=20:​GOTO 1080
1072 HN=D(1):​D(1)=D(2):​D(2)=D(3):​D(3)=HN:​NEXT J
1080 HN=D(1):​FOR J=2 TO 3:​IF D(J)>HN THEN HN=D(J)
1082 NEXT J
1090 P(I)=P(I)+HN:​IF P(I)>20 THEN ? "A straight!";:​GOTO 1100
1092 ? "Highest roll is a ";P(I);
1100 XX=XX+2:​IF P(I)>HM THEN HM=P(I)
1102 NEXT I
1110 K=0:​FOR I=1 TO N:​IF P(I)=HM THEN K=K+1:​J=I
1112 NEXT I
1120 IF K=1 THEN POSITION 1,​20:​? N$(J*10-9,​J*10);" wins the pot of $100":​M(J)=M(J)+100:​GOSUB 1470:​RETURN
1122 POSITION 1,​20:​? " We have a tie ... so let's all play another hand!":​GOSUB 1470:​GOTO 1020
1130 ? "":​K=0:​M=INT(RND(0)*5+1)*10+50
1140 J=INT(RND(0)*N+1):​IF J=IP THEN 1140
1150 M$="Show that you are a good neighbor and give ":​M$(LEN(M$)+1)=N$(J*10-9,​J*10):​M$(LEN(M$)+1)=" "
1152 M$(LEN(M$)+1)=STR$(M):​M$(LEN(M$)+1)=" dollars "
1160 M(IP)=M(IP)-M:​M(J)=M(J)+M:​GOTO 890
1170 POKE 752,​1:​? "":​? "  The bank will pay you 10 times the roll";
1171 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
1172 ? "of 2 dice. Touch any key to roll dice ";N$(IP*10-9,​IP*10):​GOSUB 1470:​J=IP:​X1=15:​X=6:​GOSUB 1450:​M=K
1174 X1=X1+6:​GOSUB 1450:​M=(M+K)*10:​M(IP)=M(IP)+M
1176 POSITION 7,​10:​? "You win ";M;" dollars."
1180 GOSUB 1470:​RETURN
1190 POKE 752,​1:​? "":​? "-- The bank will pay you ten times the roll of one die."
1191 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
1192 ? " Touch any key to roll die,​ ";N$(IP*10-9,​IP*10):​GOSUB 1470:​J=IP:​X1=18:​X=6:​GOSUB 1450:​M=K*10:​M(IP)=M(IP)+M
1194 GOTO 1176
1200 POKE 752,​1:​? "":​? "-- Roll two dice. If the total is seven you lose";
1201 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
1202 ? " $100. For any other total,​ you win $100. Touch any key to roll dice,​":​? " ";:​? N$(IP*10-9,​IP*10)
1203 GOSUB 1470
1204 J=IP:​X1=15:​X=6:​GOSUB 1450:​M=K:​X1=X1+6:​GOSUB 1450:​M=M+K
1210 POSITION 7,​10:​IF M=7 THEN ? "You lose 100 dollars!":​M(IP)=M(IP)-100:​GOTO 1220
1212 ? "You win 100 dollars!":​M(IP)=M(IP)+100
1220 GOSUB 1470:​RETURN
1230 POKE 752,​1:​? "":​? "-- You must pay to the bank ten times the roll of one die";
1231 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
1232 ? " Touch any key to roll die,​";:​? N$(IP*10-9,​IP*10):​GOSUB 1470:​J=IP:​X1=18:​X=6:​GOSUB 1450:​M=K*10
1234 M(IP)=M(IP)-M:​POSITION 7,​10:​? "You lose ";M;" dollars.":​GOSUB 1470:​RETURN
1240 POKE 752,​1:​? "":​? " -- You may bet up to $90 and roll two dice.If the";
1241 CSET=INT(RND(0)*15+1):​SETCOLOR 2,​CSET,​0:​SETCOLOR 4,​CSET,​4:​SETCOLOR 1,​CSET,​10
1242 ? " total is even,​ you collect twice your bet. Touch any key to roll dice."
1244 ? N$(IP*10-9,​IP*10):​? "How much will you bet ? ";:​J=IP:​IF IP=N THEN B=54+INT(RND(0)*4):​GOTO 1260
1250 GET #2,​B:​IF B<49 OR B>57 THEN 1250
1260 M=(B-48)*10:​? M;" dollars":​?:​?:​GOSUB 1470
1270 X1=15:​X=7:​GOSUB 1450:​P=K:​X1=X1+6:​GOSUB 1450:​P=P+K
1280 POSITION 7,​11:​IF INT(P/2)*2=P THEN ? "You win ";2*M;" dollars.":​M(IP)=M(IP)+2*M:​GOTO 1290
1282 ? "You lose ";M;" dollars.":​M(IP)=M(IP)-M
1290 GOSUB 1470:​RETURN
1300 ? "":​M=10*INT(RND(0)*5+1)+10:​M(IP)=M(IP)-M:​M$="Why don't you sweeten the pot by giving the bank "
1302 M$(LEN(M$)+1)=STR$(M):​M$(LEN(M$)+1)=" dollars.":​K=0:​GOTO 890
1310 ? "":​M=10*INT(RND(0)*5+1)+50:​M$="You hit the jackpot! Collect ":​M$(LEN(M$)+1)=STR$(M)
1312 M$(LEN(M$)+1)=" dollars.":​K=0:​M(IP)=M(IP)+M:​GOTO 890
1320 ? "":​M(IP)=M(IP)+100:​M$="Please accept this $100 bonus!":​K=0:​GOTO 890
1330 ? "":​M$="You just lost this turn!":​K=0:​GOTO 890
1340 ? "":​M$="Pay $100 tax to the bank!":​M(IP)=M(IP)-100:​K=0:​GOTO 890
1350 ? "":​M=INT(RND(0)*5+1)*10:​M(IP)=M(IP)+M*N:​FOR J=1 TO N:​M(J)=M(J)-M:​NEXT J
1352 M$="What a Bonanza! Everyone pays you ":​M$(LEN(M$)+1)=STR$(M):​M$(LEN(M$)+1)=" dollars.":​K=0:​GOTO 890
1360 ? "":​M=INT(RND(0)*5+1)*10:​M(IP)=M(IP)-M*N:​FOR J=1 TO N:​M(J)=M(J)+M:​NEXT J
1362 M$="This ought to make you mad. Give everybody ":​M$(LEN(M$)+1)=STR$(M):​M$(LEN(M$)+1)=" dollars.":​K=0:​GOTO 890
1370 ? "":​?:​? " ":​?:​?:​? " You and the Atari are in a contest to"
1372 ? " see who will build his $100 bankroll into $1000 first. Money is made and"
1374 ? " lost through a series of games of chance from horse racing and dice to"
1380 ? " lotteries and sweepstakes! If you should lose all your money,​your";
1382 ? " IOU will be accepted (as long as you pay it back with interest).":​?:​? " ":​K=0
1383 GOTO 910
1450 POKE 764,​255:​S=1:​POKE 752,​1
1452 IF J<>N THEN 1460
1454 FOR L=1 TO RND(0)*50+1:​K=INT(RND(0)*6+1):​POSITION X1,​X:​? D$(K*17-16,​K*17);:​POKE 53279,​RND(0)*4:​NEXT L
1455 GOTO 1462
1460 B=PEEK(764):​K=INT(RND(0)*6+1):​POSITION X1,​X:​? D$(K*17-16,​K*17);:​POKE 53279,​RND(0)*4:​IF B=255 THEN 1460
1462 POKE 764,​255:​POKE 752,​S:​RETURN
1469 STOP
1470 POKE 764,​255:​POSITION 1,​23:​? " Touch any key to continue ";
1475 IF RND(0)<0.11 THEN S=RND(0)*70+30:​FOR TI=S TO S-8 STEP -4:​SOUND 0,​TI,​10,​10:​NEXT TI:​SOUND 0,​0,​0,​0
1480 IF PEEK(764)=255 THEN 1475
1482 POKE 764,​255:​POSITION 6,​23:​? " ";:​RETURN	

• Download link 1

• Download link 1
• Download link 2