Atari 8-bit Source code

10 REM **** MASTERMIND ****
20 DIM NUMBER(4),​GUESS(4),​G$(4)
25 DIM PR(4),​PW(4),​REPLY$(3):​GRAPHICS 0
30 NR=0
40 NL=0
45 PRINT
50 PRINT "HI,​I AM AN ATARI COMPUTER."
60 PRINT "I AM THINKING OF A FOUR DIGIT NUMBER."
70 PRINT "YOU HAVE TEN CHANCES TO GUESS IT."
80 PRINT "AFTER EACH GUESS,​I WILL TELL YOU HOW"
90 PRINT "MANY NUMBERS YOU HAVE RIGHT AND IN"
100 PRINT "THE RIGHT PLACE AND HOW MANY NUMBERS"
110 PRINT "YOU HAVE RIGHT BUT IN THE WRONG PLACE."
115 PRINT
120 PRINT "GOOD LUCK"
130 PRINT
140 COUNTER=10
150 FOR I=1 TO 4
155 NUM=10*RND(I)
160 NUMBER(I)=INT(NUM)
170 NEXT I
180 PRINT "ALL RIGHT,​YOU HAVE TEN CHANCES"
185 TNPR=0:​TNPW=0
190 INPUT G$
195 IOK=0
196 IF LEN(G$)<>4 THEN PRINT "I WILL ACCEPT ONLY FOUR DIGIT NUMBERS":​GOTO 190
200 FOR I=1 TO 4
203 REM *** CHECK FOR VALID GUESS ***
204 IF ASC(G$(I,​I))>57 THEN IOK=1
205 IF ASC(G$(I,​I))<48 THEN IOK=1
206 IF IOK=1 THEN PRINT "I WILL ACCEPT ONLY FOUR DIGIT NUMBERS":​GOTO 190
210 GUESS(I)=VAL(G$(I,​I)):​PR(I)=0:​PW(I)=0
220 IF GUESS(I)=NUMBER(I) THEN PR(I)=1:​TNPR=TNPR+1:​PW(I)=1
230 NEXT I
240 IF TNPR=4 THEN GOTO 460
250 I=0
255 I=I+1
260 IF I>4 THEN GOTO 350
270 IF PR(I)=1 THEN GOTO 255
280 J=0
285 J=J+1
290 IF J>4 THEN GOTO 255
300 IF PW(J)=1 THEN GOTO 285
310 IF NUMBER(I)<>GUESS(J) THEN GOTO 285
320 PW(J)=1
330 TNPW=TNPW+1
340 GOTO 255
350 COUNTER=COUNTER-1
360 IF COUNTER=0 THEN GOTO 430
365 PRINT
370 PRINT TNPR;" RIGHT AND IN THE RIGHT PLACE"
380 PRINT TNPW;" RIGHT BUT IN THE WRONG PLACE"
390 IF COUNTER=5 THEN PRINT "YOU HAVE 5 CHANCES LEFT"
395 PRINT
400 IF COUNTER=2 THEN PRINT "YOU HAVE 2 CHANCES LEFT"
410 IF COUNTER=1 THEN PRINT "YOU HAVE 1 CHANCE LEFT-DON'T BLOW IT"
420 GOTO 185
430 PRINT
435 PRINT "SORRY,​THE NUMBER IS ";NUMBER(1);NUMBER(2);NUMBER(3);NUMBER(4)
440 NL=NL+1
450 GOTO 480
460 PRINT
465 NR=NR+1
470 PRINT "CONGRATULATIONS YOU GUESSED IT"
480 TOTALN=TOTALN+1
485 PRINT
490 PRINT "DO YOU WANT TO PLAY AGAIN?"
500 PRINT "INPUT YES OR NO";
510 INPUT REPLY$
520 IF REPLY$="YES" THEN GOTO 140
525 PRINT
530 PRINT "YOU HAVE PLAYED A TOTAL OF ";TOTALN;" GAMES"
540 PRINT "YOU WON ";NR;" GAMES"
550 PRINT "YOU LOST ";NL;" GAMES"
560 END	

• Download link 1

• Download link 1