Atari 8-bit Source code

2 REM *** ATARI LOGIK ***
3 REM *** ELEKTRONIKA 1/88 ***
4 REM *******************************
5 REM PRETUKAL ING.J.VACHA,​NAMEST N.O.
10 DIM C(5),​CI$(5),​B$(1),​D(5),​G$(1)
20 C(1)=INT(RND(0)*9)+1
25 POKUS=0
30 FOR I=2 TO 5
40 LET C(I)=INT(RND(0)*9)+1
50 FOR K=1 TO I-1
60 IF C(I)=C(K) THEN 40
70 NEXT K:​NEXT I
80 PRINT CHR$(125):​POKE 85,​6
90 PRINT "MYSLIM SI PETICIFERNE CISLO"
91 PRINT "CISLICE 1 AZ 9 SE NESMI OPAKOVAT"
95 PRINT " HADEJ !":​PRINT:​PRINT
100 POKE 85,​10:​PRINT "ZASAH VEDLE SPATNE POKUS"
110 INPUT CISLO:​X=PEEK(84):​POKUS=POKUS+1
120 LET XY=LEN(STR$(CISLO))
130 IF XY<>5 THEN PRINT "SPATNE ZADANE!":​GOTO 110
140 LET CI$=STR$(CISLO)
150 FOR I=1 TO 5:​B$=CI$(I):​LET D(I)=VAL(B$):​NEXT I
160 FOR J=1 TO 5:​LET Z=D(J)
170 FOR I=1 TO 5
180 IF I=J THEN GOTO 200
190 IF Z=D(I) THEN PRINT "CISLA SE NESMI OPAKOVAT!":​GOTO 110
200 NEXT I
210 NEXT J
220 ZASAH=0:​VEDLE=0:​SPATNE=0
230 FOR K=1 TO 5
240 IF C(K)=D(K) THEN ZASAH=ZASAH+1:​C(K)=C(K)*(-1)
245 NEXT K
250 FOR I=1 TO 5:​FOR J=1 TO 5
260 IF D(I)=C(J) THEN VEDLE=VEDLE+1
270 NEXT J:​NEXT I
280 FOR I=1 TO 5:​C(I)=ABS(C(I)):​NEXT I
290 SPATNE=5-(VEDLE+ZASAH)
300 POKE 84,​X-1:​POKE 85,​12
310 PRINT ZASAH;" ";VEDLE;" ";SPATNE;" ";POKUS
320 IF ZASAH=5 THEN PRINT:​PRINT "UHODL JSI,​ MYSLENE CISLO JE ";CISLO:​GOTO 340
325 IF POKUS=20 THEN PRINT "S TVOU INTELIGENCI TO NENI PRILIS SLAVNE"
326 IF POKUS=50 THEN PRINT "INTELIGENCE PODPRUMERNA"
330 GOTO 110
340 PRINT "CHCES JESTE HRAT? A/N":​INPUT G$
350 IF G$="A" THEN 20
360 END	

• Download link 1
• Download link 2